UltraVNCの小技(2) — 簡易インストーラの作成

改造したUltraVNC（サーバ）ですが、当然ながらインストールしないと話になりません。

という訳で、至極簡単なインストーラをバッチファイル（！）で作成してみました。

やることは、３つだけ。

1. 必要なファイルのコピー
2. Windows ファイアウォールの設定
3. UltraVNCサービスの設定（登録と起動）

echo off
REM UltraVNC installer Modoki ver. 0.02

SET TARGETFOLDER=%ProgramFiles%\UltraVNC
SET EXEFILE=winvnc_32.exe
SET INIFILE=ultravnc.ini
SET DLLFILES=authadmin.dll authSSP.dll ldapauth.dll ldapauth9x.dll ldapauthnt4.dll logging.dll logmessages.dll vnchooks.dll workgrpdomnt4.dll
SET FILES=%EXEFILE% %INIFILE% %DLLFILES%
SET WINVNCSERVICE=uvnc_service
SET WINVNCPORT=5900
SET ALLOWIP=192.168.0.0/24

SET PWD=%~d0%~p0

REM *** ターゲットフォルダ内にファイルをコピー ***
mkdir "%TARGETFOLDER%"
for %%f in ( %FILES% ) do (
copy "%PWD%%%f" "%TARGETFOLDER%¥%%f"
if errorlevel 1 goto :ERROR
)

REM *** Windowsファイアウォールの設定 ***
for %%i in ( %ALLOWIP% ) do (
netsh advfirewall firewall add rule name=%WINVNCSERVICE% dir=in protocol=tcp remoteip=%%i localport=%WINVNCPORT% action=allow
)

REM *** UltraVNCサービスの登録と起動 ***
sc create %WINVNCSERVICE% binpath= "%TARGETFOLDER%\%EXEFILE% -service" start= auto
if errorlevel 1 goto :ERROR
sc start %WINVNCSERVICE%
if errorlevel 1 goto :ERROR

:SUCCESS
echo Success.
pause
goto :END

:ERROR
echo Error!
pause
goto :END

:END

「管理者として実行」してください（Vista/7等）。

ultravnc.ini ファイルは、uvnc_settings.exe を使って作成しましょう。

アンインストールは手作業で、というか、インストーラを元にして直ぐアンインストールバッチが書けますね。